Unit Tangent, Normal, and Binormal vectors

> restart;

> with(linalg):

Warning, new definition for norm

Warning, new definition for trace

Maple made a change when it upgraded from Release 4 to Release 5.1 which impacts in a clumsy way with the dot product . It now allows the dot product to act on more general vector spaces. Unfortunately for us, if u and v are vectors, the dot product command must now be entered in the form .

>dotprod(u, v, orthogonal);

I usually tell my students to introduce their own dot product command by writing

> dot:=(u,v)->dotprod(u,v,orthogonal);

Example: Let be the curve defined by the vector valued position function

r(t) = sin(t) i +(cos(t)-sin(t)) j +cos(3t) k

for t in the closed interval between 0 and . Compute the vectors T , N , B at the point on corresponding to . Plot along with the frame {T, N, B} based at . Finally, determine the curvature of at .

> r:=map(unapply,vector([sin(t),cos(t)-sin(t),cos(3*t)]),t);

> rp:=map(D,r);

> size:=proc(v) sqrt(dot(v,v));end;

> T:=map(unapply,scalarmul(rp(t),1/size(rp(t))),t);

> T1:=T(Pi/4);

The principal normal vector N as an expression in t is pretty nasty, so we turn immediately to an evaluation at .

> N1:=normalize(map(D,T)(Pi/4));

> B1:=crossprod(T1,N1);

The TNB frame at is the collection { T1, N1, B1 } based at .

I think that the new version of Maple has tools for placing vectors into graphics. I haven't looked very carefully at the details so I will proceed instead with a simple devise for turning a vector into a line segment. We can use our imagination to place an arrow at the tip of the line segment. This, anyway, is how I created a graphic in Maple V R4.

> vline:=proc(p,v) L:=matadd(p,scalarmul(v,t));[L[1],L[2],L[3],t=0..1];end;

Warning, `L` is implicitly declared local

> frame:=vline(r(Pi/4),T1),vline(r(Pi/4),N1),vline(r(Pi/4),B1);

> c:=[r[1](t),r[2](t),r[3](t),t=0..2*Pi];

> with(plots):

> spacecurve({c,frame},scaling=CONSTRAINED,thickness=2);

Look at this plot. Better yet, determine frames at several points, and look at a plot that shows the curve together with several frames. Move the plot around with the mouse to get a good look at
the curve and its various frames. Notice how N always points to the concave side of the
curve, towards the center of the circle of curvature.

> kappa:=norm(map(D,T)(Pi/4),2)/norm(rp(Pi/4),2);

>

>